/*
 * Copyright (C) 2024 Apple Inc. All rights reserved.
 *
 * Redistribution and use in source and binary forms, with or without
 * modification, are permitted provided that the following conditions
 * are met:
 * 1. Redistributions of source code must retain the above copyright
 *    notice, this list of conditions and the following disclaimer.
 * 2. Redistributions in binary form must reproduce the above copyright
 *    notice, this list of conditions and the following disclaimer in the
 *    documentation and/or other materials provided with the distribution.
 *
 * THIS SOFTWARE IS PROVIDED BY APPLE INC. AND ITS CONTRIBUTORS ``AS IS''
 * AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO,
 * THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
 * PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL APPLE INC. OR ITS CONTRIBUTORS
 * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
 * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
 * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
 * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
 * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
 * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF
 * THE POSSIBILITY OF SUCH DAMAGE.
 */

#import "config.h"

#import "PlatformUtilities.h"
#import "TestWKWebView.h"
#import <WebKit/WKWebViewPrivateForTesting.h>
#import <WebKit/WebKit.h>

namespace TestWebKitAPI {

TEST(NowPlayingMetadataObserver, VideoTitle)
{
    auto configuration = adoptNS([[WKWebViewConfiguration alloc] init]);
    [configuration setMediaTypesRequiringUserActionForPlayback:WKAudiovisualMediaTypeNone];

    auto webView = adoptNS([[TestWKWebView alloc] initWithFrame:NSMakeRect(0, 0, 480, 320) configuration:configuration.get()]);
    [webView loadTestPageNamed:@"large-video-test-now-playing"];
    [webView waitForMessage:@"playing"];

    __block bool hasNowPlayingMetadata = false;
    __block RetainPtr<_WKNowPlayingMetadata> nowPlayingMetadata = nil;
    [webView _setNowPlayingMetadataObserver:^(_WKNowPlayingMetadata * _Nonnull metadata) {
        nowPlayingMetadata = metadata;
        hasNowPlayingMetadata = true;
    }];

    while (![[nowPlayingMetadata title] length]) {
        hasNowPlayingMetadata = false;
        TestWebKitAPI::Util::run(&hasNowPlayingMetadata);
    }

    ASSERT_STREQ("foo", [nowPlayingMetadata title].UTF8String);
}

TEST(NowPlayingMetadataObserver, VideoTitleUpdatedByMediaSession)
{
    auto configuration = adoptNS([[WKWebViewConfiguration alloc] init]);
    [configuration setMediaTypesRequiringUserActionForPlayback:WKAudiovisualMediaTypeNone];

    auto webView = adoptNS([[TestWKWebView alloc] initWithFrame:NSMakeRect(0, 0, 480, 320) configuration:configuration.get()]);
    [webView loadTestPageNamed:@"large-video-test-now-playing"];
    [webView waitForMessage:@"playing"];

    __block bool hasNowPlayingMetadata = false;
    __block RetainPtr<_WKNowPlayingMetadata> nowPlayingMetadata = nil;
    [webView _setNowPlayingMetadataObserver:^(_WKNowPlayingMetadata * _Nonnull metadata) {
        nowPlayingMetadata = metadata;
        hasNowPlayingMetadata = true;
    }];

    while (![[nowPlayingMetadata title] length]) {
        hasNowPlayingMetadata = false;
        TestWebKitAPI::Util::run(&hasNowPlayingMetadata);
    }

    ASSERT_STREQ("foo", [nowPlayingMetadata title].UTF8String);

    [webView stringByEvaluatingJavaScript:@"setMediaSessionMetadata()"];

    hasNowPlayingMetadata = false;
    TestWebKitAPI::Util::run(&hasNowPlayingMetadata);

    ASSERT_STREQ("bar", [nowPlayingMetadata title].UTF8String);
}

} // namespace TestWebKitAPI