/*
 * Copyright (C) 2024 Apple Inc. All rights reserved.
 *
 * Redistribution and use in source and binary forms, with or without
 * modification, are permitted provided that the following conditions
 * are met:
 * 1. Redistributions of source code must retain the above copyright
 *    notice, this list of conditions and the following disclaimer.
 * 2. Redistributions in binary form must reproduce the above copyright
 *    notice, this list of conditions and the following disclaimer in the
 *    documentation and/or other materials provided with the distribution.
 *
 * THIS SOFTWARE IS PROVIDED BY APPLE INC. AND ITS CONTRIBUTORS ``AS IS''
 * AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO,
 * THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
 * PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL APPLE INC. OR ITS CONTRIBUTORS
 * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
 * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
 * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
 * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
 * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
 * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF
 * THE POSSIBILITY OF SUCH DAMAGE.
 */

#import "config.h"

#import "PlatformUtilities.h"
#import "Test.h"
#import "TestWKWebView.h"
#import "WKWebViewConfigurationExtras.h"
#import <WebKit/WKWebViewPrivate.h>
#import <wtf/BlockPtr.h>
#import <wtf/RetainPtr.h>

#if HAVE(SPATIAL_TRACKING_LABEL)
TEST(WKWebView, DefaultSTSLabel)
{
    auto *configuration = [WKWebViewConfiguration _test_configurationWithTestPlugInClassName:@"WebProcessPlugInWithInternals" configureJSCForTesting:YES];
    auto webView = adoptNS([[TestWKWebView alloc] initWithFrame:NSMakeRect(0, 0, 300, 300) configuration:configuration addToWindow:YES]);

    [webView synchronouslyLoadHTMLString:@"<body></body>"];

    auto getDefaultSTSLabel = [&] {
        return [webView stringByEvaluatingJavaScript:@"internals.defaultSpatialTrackingLabel"];
    };

    auto testDefaultSTSLabelEventually = [&](auto test) {
        TestWebKitAPI::Util::waitFor([&] {
            return test(getDefaultSTSLabel());
        });
    };

    testDefaultSTSLabelEventually([](auto* label) { return ![label isEqualToString:@""]; });
    ASSERT_STRNE(getDefaultSTSLabel().UTF8String, "");

    [webView removeFromSuperview];

    testDefaultSTSLabelEventually([](auto* label) { return [label isEqualToString:@""]; });
    ASSERT_STREQ(getDefaultSTSLabel().UTF8String, "");

    [webView addToTestWindow];
    [webView _setDefaultSTSLabel:@"default-sts-label"];

    testDefaultSTSLabelEventually([](auto* label) { return [label isEqualToString:@"default-sts-label"]; });
    ASSERT_STREQ(getDefaultSTSLabel().UTF8String, "default-sts-label");

    [webView removeFromSuperview];

    testDefaultSTSLabelEventually([](auto* label) { return [label isEqualToString:@"default-sts-label"]; });
    ASSERT_STREQ(getDefaultSTSLabel().UTF8String, "default-sts-label");
}
#endif